第10回.標準モジュールとフォーム間のデータ受け渡しⅡ
ユーザーフォーム入門として基礎から解説します。
２．標準モジュールのグローバル変数を使う
３．標準モジュールからフォームのコントロールを操作する
４．Subプロシージャーの引数を使う
５．Functionプロシージャーの戻り値を使う。
では、いよいよ４．５．を解説しましょう。
ここが、本題です。
Subプロシージャーの引数を使う
まずは、フォームモジュールに以下を作成します。
プロシージャー名のdoModalのModalは、
フォーム表示（モーダル）方法の名称よりとっています。
モーダル・モードレスについては、以下で解説しています。
Option Explicit
Private ActiveRow As Long
Public Sub doModal(ByVal argRow As Long)
ActiveRow = argRow
With Worksheets("顧客マスタ")
Me.txtコード.Text = .Cells(ActiveRow, 1)
Me.txt漢字名称.Text = .Cells(ActiveRow, 2)
Me.txtカナ名称.Text = .Cells(ActiveRow, 3)
End With
Me.Show
End Sub
プロシージャー名のdoModalのModalは、
フォーム表示（モーダル）方法の名称よりとっています。
モーダル・モードレスについては、以下で解説しています。
そして、
標準モジュールでは、
要点としては、
doModalの引数で値を受け取り、処理後に自身を表示(Me.Show)している所です。
標準モジュールでは、
Sub FormShow()
Call frmSample.doModal(ActiveCell.Row)
End Sub
要点としては、
Functionプロシージャーの戻り値を使う
「OK」ボタンを押されたか「閉じる」ボタンを押されたか、
これらを標準モジュールで判断してみましょう。
フォームモジュールを以下に変更します。
そして、標準モジュールで、
最初のSubだったdoModalをFunctionに変更しただけですね、
これに伴い、ボタンの判断をする為に、
Private blnOk As Boolean
この変数を使うようにしました。
ただ、ちょっと気を付けてもらいたいのは、
Unload Me
この後でフォームのコントロールを参照するのは、本当は問題があります。
上記では問題なく動きますが、やはり、あまり良くありません。
そこで、
Unload Me
この代わりに、
Me.Hide
（Hideはフォームを非表示にしてShowの次のステートメントに進みます）として、
標準モジュールに戻ってから、Unloadした方が良いでしょう。
出来上がりとしては、
これらを標準モジュールで判断してみましょう。
Option Explicit
Private ActiveRow As Long
Private blnOk As Boolean
Public Function doModal(ByVal argRow As Long) As Boolean
ActiveRow = argRow
With Worksheets("顧客マスタ")
Me.txtコード.Text = .Cells(ActiveRow, 1)
Me.txt漢字名称.Text = .Cells(ActiveRow, 2)
Me.txtカナ名称.Text = .Cells(ActiveRow, 3)
End With
blnOk = False
Me.Show
doModal = blnOk
End Function
Private Sub btnOk_Click()
Dim lastRow As Long
With Worksheets("顧客マスタ")
lastRow = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
.Cells(lastRow, 1) = Me.txtコード.Text
.Cells(lastRow, 2) = Me.txt漢字名称.Text
.Cells(lastRow, 3) = Me.txtカナ名称.Text
End With
blnOk = True
Unload Me
End Sub
Private Sub btnCancel_Click()
blnOk = False
Unload Me
End Sub
そして、標準モジュールで、
Sub FormShow()
If frmSample.doModal(ActiveCell.Row) = True Then
MsgBox "「OK」が押されました。"
Else
MsgBox "「閉じる」が押されました。"
End If
End Sub
最初のSubだったdoModalをFunctionに変更しただけですね、
これに伴い、ボタンの判断をする為に、
Private blnOk As Boolean
この変数を使うようにしました。
Unload Me
この後でフォームのコントロールを参照するのは、本当は問題があります。
上記では問題なく動きますが、やはり、あまり良くありません。
そこで、
Unload Me
この代わりに、
Me.Hide
（Hideはフォームを非表示にしてShowの次のステートメントに進みます）として、
標準モジュールに戻ってから、Unloadした方が良いでしょう。
Option Explicit
Private ActiveRow As Long
Private blnOk As Boolean
Public Function doModal(ByVal argRow As Long) As Boolean
ActiveRow = argRow
With Worksheets("顧客マスタ")
Me.txtコード.Text = .Cells(ActiveRow, 1)
Me.txt漢字名称.Text = .Cells(ActiveRow, 2)
Me.txtカナ名称.Text = .Cells(ActiveRow, 3)
End With
blnOk = False
Me.Show
doModal = blnOk
End Function
Private Sub btnOk_Click()
Dim lastRow As Long
With Worksheets("顧客マスタ")
lastRow = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
.Cells(lastRow, 1) = Me.txtコード.Text
.Cells(lastRow, 2) = Me.txt漢字名称.Text
.Cells(lastRow, 3) = Me.txtカナ名称.Text
End With
blnOk = True
Me.Hide
End Sub
Private Sub btnCancel_Click()
blnOk = False
Me.Hide
End Sub
Sub FormShow()
If frmSample.doModal(ActiveCell.Row) = True Then
MsgBox "「OK」が押されました。"
Else
MsgBox "「閉じる」が押されました。"
End If
Unload frmSample
End Sub
標準モジュールとフォーム間のデータ受け渡しについて
前回と今回で、4通りの方法を紹介しました。
どれが良いと言う事もありませんし、
実現したい処理に応じて、これらの方法を組み合わせることも必要になれます。
お勧めとしては、４．５．の方法になりますが、
最も簡単で最も確実なのは、２．になります。
ただし、
プログラムの品質を考えた時、グローバル変数を多用するのは避けたいところですので、
どの方法で実装するかについては良く検討してください。
どれが良いと言う事もありませんし、
実現したい処理に応じて、これらの方法を組み合わせることも必要になれます。
最も簡単で最も確実なのは、２．になります。
ただし、
プログラムの品質を考えた時、グローバル変数を多用するのは避けたいところですので、
どの方法で実装するかについては良く検討してください。
同じテーマ「ユーザーフォーム入門」の記事
・前回までに作成したユーザーフォーム ・ワークシートの用意 ・OKボタンクリック時のイベントプロシージャー作成 ・ユーザーフォームのインテリセンス
第8回.セルの値をテキストボックスへ・Initializeイベントプロシージャーの追加 ・InitializeイベントプロシージャーのVBAコード ・各モジュール間でのデータ受け渡し方法
第9回.標準モジュールとフォーム間のデータ受け渡しⅠ・前回までに作成したVBA ・フォーム側でアクティブセルの行数を知る方法 ・標準モジュールのグローバル変数を使う ・標準モジュールからフォームのコントロールを操作する
第10回.標準モジュールとフォーム間のデータ受け渡しⅡ第11回.コンボボックス(ComboBox)の追加
・コンボボックスの追加 ・コンボボックスのプロパティ・メソッド ・コンボボックスで選択した値を取得 ・コンボボックスの指定リストを選択状態にする ・複数列のコンボボックス
第12回.リストボックス(ListBox)の追加・リストボックスの追加 ・リストボックスのプロパィ ・Listプロパティ ・Columnプロパティ ・RowSourceプロパティ ・選択されたリスト項目の取得 ・リストボックスの複数選択 ・IntegralHeightプロパティ
第13回.チェックボックス(CheckBox)の追加・チェックボックスの追加 ・チェック状態の設定 ・チェック状態の取得
第14回.オプションボタン(OptionButton)の追加・オプションボタンの追加 ・オプションボタンの状態設定 ・チェック状態の判定 ・オプションボタンのグループ化
第15回.ここまでの整理と全VBA・ワークシート ・シートモジュール ・標準モジュール ・フォーム ・フォームモジュール
第16回.アクティブコントロールに色を付ける・フォームモジュール ・EnterイベントとExitイベントをセットで使う方法 ・対応するラベルのフォントを太字にする
第17回.Enterキーで次のコントロールに移動する・ユーザーフォームでのEnterキー動作について ・KeyDownイベント ・KeyPressイベント
新着記事NEW ・・・新着記事一覧を見る
TRIMRANGE関数（セル範囲をトリム：端の空白セルを除外）｜エクセル入門(2024-08-30)
正規表現関数（REGEXTEST,REGEXREPLACE,REGEXEXTRACT）｜エクセル入門(2024-07-02)
エクセルが起動しない、Excelが立ち上がらない｜エクセル雑感(2024-04-11)
ブール型（Boolean）のis変数・フラグについて｜VBA技術解説(2024-04-05)
テキストの内容によって図形を削除する｜VBA技術解説(2024-04-02)
ExcelマクロVBA入門目次｜エクセルの神髄(2024-03-20)
VBA10大躓きポイント（初心者が躓きやすいポイント）｜VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成｜ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。｜エクセル雑感(2024-02-17)
初級脱出10問パック｜VBA練習問題(2024-01-24)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
3.変数宣言のDimとデータ型｜VBA入門
4.RangeとCellsの使い方｜VBA入門
5.繰り返し処理（For Next)｜VBA入門
6.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
7.メッセージボックス(MsgBox関数)｜VBA入門
8.セルのクリア（Clear,ClearContents）｜VBA入門
9.条件分岐（Select Case）｜VBA入門
10.ブック・シートの選択（Select,Activate）｜VBA入門
- ホーム
- マクロVBA応用編
- ユーザーフォーム入門
- 標準モジュールとフォーム間のデータ受け渡しⅡ
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。