VBA練習問題
VBA100本ノック 67本目:ComboBoxとListBox

VBAを100本の練習問題で鍛えます
公開日:2021-01-15 最終更新日:2021-02-22

VBA100本ノック 67本目:ComboBoxとListBox


ユーザーフォームのコンボボックスでデータを絞り込んでリストボックスに表示する問題です。


ツイッター連動企画です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。

VBAテスト用のサンプルデータは、VBA100本ノックの目次ページ からもダウンロードできます。
マクロVBAを初心者向けの基本から上級者向けの高度な内容までサンプルコードを掲載し解説しています。エクセル関数・機能・基本操作の入門解説からマクロVBAまでエクセル全般を網羅しています。


出題

出題ツイートへのリンク

#VBA100本ノック 67本目
ユーザーフォームのListBoxに、ComboBoxの値で「リスト」シートのA列を絞りこんだデータを表示します。
ListBoxにはB列~D列を列見出しを付けて表示してください。
適宜作業シートを使用。
※オブジェクト名は任意
※コンボは都道府県が設定済としてイベントの作成です。

マクロ VBA 100本ノック


サンプルファイルです。
https://excel-ubara.com/vba100sample/VBA100_67.xlsm
https://excel-ubara.com/vba100sample/VBA100_67.zip


VBA作成タイム

この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。


他の人の回答および解説を見て、書いたVBAを見直してみましょう。


頂いた回答

解説

コンボボックスの変更はChangeイベントを使います。
リストボックスの設定は、
複数列:ColumnCount
列幅:ColumnWidths
見出し:ColumnHeads
データ:RowSource
見出しはRowSourceがセル範囲の場合のみ有効。
RowSourceは見出し行を除いたセル範囲のアドレスを文字列で指定します。

Private Sub cmb都道府県_Change()
  Application.ScreenUpdating = False
  Dim ws As Worksheet: Set ws = ThisWorkbook.Worksheets("リスト")
  With lst個人
    .ColumnCount = 4
    .ColumnWidths = "0;95;30"
    .ColumnHeads = True
    .RowSource = getListAddress(ws, 1, Me.cmb都道府県.Value)
  End With
  Application.ScreenUpdating = True
End Sub

Private Function getListAddress(ByVal ws As Worksheet, ByVal aCol As Long, ByVal aStr As String) As String
  Dim wsWork As Worksheet
  Set wsWork = getWorksheet(ThisWorkbook, "work")
  wsWork.Cells.Clear
  
  ws.AutoFilterMode = False
  With ws.Range("A1").CurrentRegion
    .AutoFilter aCol, aStr
    .Copy Destination:=wsWork.Range("A1")
  End With
  ws.AutoFilterMode = False
  
  With wsWork.Range("A1").CurrentRegion
    If .Rows.Count = 1 Then Exit Function
    getListAddress = Intersect(.Cells, .Offset(1)).Address(external:=True)
  End With
End Function

Private Function getWorksheet(ByVal wb As Workbook, ByVal aName As String) As Worksheet
  On Error Resume Next
  Set getWorksheet = wb.Worksheets(aName)
  If Err.Number = 0 Then Exit Function
  
  Dim ws As Worksheet: Set ws = ActiveSheet
  Set getWorksheet = wb.Worksheets.Add(after:=wb.Sheets(wb.Sheets.Count))
  getWorksheet.Name = aName
  getWorksheet.Visible = xlSheetVeryHidden
  ws.Select
End Function


表示列だけに範囲を絞っても良いですが、列幅を0にすれば見た目は列が無い状態になります。
この非表示列は、リストから選択されているデータを取得する時に使う事も出来ます。
記事にはVBAコードと参考ページへのリンクを掲載しています。


補足

サイト内関連ページをご覧ください。


サイト内関連ページ

ユーザーフォーム入門
エクセル(Excel)マクロ(VBA)をやっていればユーザーフォームの存在を知り、そしてユーザーフォームを使いたくなります。使いたくなるというより、使った方が良い場合が出てきます。しかし、ユーザーフォームは少々とっつきにくく、使い始めて使いこなすには、各種コントロールの特性を理解し、イベントについても深い知識が必要…
第11回.コンボボックス(ComboBox)の追加
・コンボボックスの追加 ・コンボボックスのプロパティ・メソッド ・コンボボックスで選択した値を取得 ・コンボボックスの指定リストを選択状態にする ・複数列のコンボボックス
第12回.リストボックス(ListBox)の追加
・リストボックスの追加 ・リストボックスのプロパィ ・Listプロパティ ・Columnプロパティ ・RowSourceプロパティ ・選択されたリスト項目の取得 ・リストボックスの複数選択 ・IntegralHeightプロパティ




同じテーマ「VBA100本ノック」の記事

64本目:リンクされた図(カメラ機能)

・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
65本目:固定長テキスト出力
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
66本目:全サブフォルダからファイルを探す
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
67本目:ComboBoxとListBox
68本目:全テキストボックスの転記
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
69本目:ダブルクリックでセル結合を解除
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
70本目:ステータスバーに1秒ごとに時刻が表示
・出題 ・頂いた回答 ・解説 ・補足 ・追記 ・サイト内関連ページ
71本目:パワーポイントへグラフを貼り付け
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
72本目:ITをDXに変換(文字列操作)
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
73本目:新規ブックにボタン作成しマクロ登録
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
74本目:1シート複数表をDB形式に変換
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ


新着記事NEW ・・・新着記事一覧を見る

エクセルが起動しない、Excelが立ち上がらない|エクセル雑感(2024-04-11)
ブール型(Boolean)のis変数・フラグについて|VBA技術解説(2024-04-05)
テキストの内容によって図形を削除する|VBA技術解説(2024-04-02)
ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
3.変数宣言のDimとデータ型|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.RangeとCellsの使い方|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.メッセージボックス(MsgBox関数)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.ひらがな⇔カタカナの変換|エクセル基本操作




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。


このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ