VBA100本ノック 72本目：ITをDXに変換（文字列操作）
引数の文字列に対して、全ての"IT"を"DX"に置換するFunctionを作成する問題です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。
出題
引数の文字列に以下の処理を行い文字列で返すFunctionを作成。
全ての"IT"を"DX"に置換
※大小文字全半角問わず
※直前または直後がアルファベットの場合は対象外
※空白及び'は除いて判定
置換する："ＩＴ","と IT","itは","IT 99"
しない："ＧＩＴ","site","It's","it is"
Array("ＩＴ", "とIT", "it は", "IT99", "ＧＩＴ", "site", "It's", "itはITでIt's ITでもITだ")
VBA作成タイム
この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。
他の人の回答および解説を見て、書いたVBAを見直してみましょう。
頂いた回答
解説
大文字小文字・全角半角を区別しないためにStrConvを使っています。
ITを見つけたら、前または後ろの文字を順に探してアルファベットを確認しています。
置換文字数が同じなのでMidステートメントで置換しています。
Function VBA100_72_01(ByVal aStr As String) As String
Dim i As Long, flgAlpha As Boolean
For i = 1 To Len(aStr) - 1
If StrConv(Mid(aStr, i, 2), vbNarrow + vbUpperCase) = "IT" Then
If isDX(Left(aStr, i - 1), True) And _
isDX(Mid(aStr, i + 2), False) Then
Mid(aStr, i, 2) = "DX"
End If
End If
Next
VBA100_72_01 = aStr
End Function
Function isDX(ByVal aStr As String, ByVal isRev As Boolean) As Boolean
Dim iStart As Long: iStart = IIf(isRev, Len(aStr), 1)
Dim iEnd As Long: iEnd = IIf(isRev, 1, Len(aStr))
Dim iStep As Long: iStep = IIf(isRev, -1, 1)
Dim i As Long
For i = iStart To iEnd Step iStep
Select Case StrConv(Mid(aStr, i, 1), vbNarrow + vbUpperCase)
Case " ", "'"
Case "A" To "Z"
Exit Function
Case Else
Exit For
End Select
Next
isDX = True
End Function
正規表現なら簡単そうに思える、、、のですが、意外に難しいですね。
正規表現については、記事補足に簡単な説明とともに記載しました。
補足
私も考えたのですが、結局これが一番良さそうかなと思ったので、簡単に解説します。
Function VBA100_72_03(ByVal aStr As String) As String
' With CreateObject("VBScript.RegExp")
With New RegExp
.Global = True
.IgnoreCase = True
.Pattern = "(^|[^A-ZＡ-Ｚ ’'])([ ’']*)([IＩ][TＴ])(?![ ’']*[A-ZＡ-Ｚ])"
VBA100_72_02 = .Replace(aStr, "$1$2DX")
End With
End Function
(^|[^A-ZＡ-Ｚ ’'])
^が文字列の先頭の指定です。
先頭に達するか、
[]の中の文字リストのどれにも（^なので）該当しなければ事になります。
空白と'（シングルクォート）の0個以上
連続空白対応です。
半角全角混在のIT。
否定先読みになります。
ITの評価の時点で、後ろの文字を先に読み込んで評価しています。
!なので否定です。
ITの後ろに、ここで指定する文字以外がきていたらという条件になります。
この$1と$2は、パターンのグループの番号です。
(^|[^A-ZＡ-Ｚ ’']) ・・・ $1
([ ’']*) ・・・ $2
それぞれに取得された文字列が入っています。
つまり、
「$1$2IT」このように取得されるので、それを$1$2DXに置換しています。
サイト内関連ページ
同じテーマ「VBA100本ノック」の記事
69本目：ダブルクリックでセル結合を解除
70本目：ステータスバーに1秒ごとに時刻が表示
71本目：パワーポイントへグラフを貼り付け
72本目：ITをDXに変換（文字列操作）
73本目：新規ブックにボタン作成しマクロ登録
74本目：1シート複数表をDB形式に変換
75本目：ログインフォームの作成
76本目：ボタンの表示名の位置へ移動
77本目：シート挿入イベント
78本目：グラフのデータ範囲拡張
79本目：Wordにセル範囲を図として挿入
新着記事NEW ・・・新着記事一覧を見る
エクセル試験3：月間の所定労働時間｜エクセル練習問題(2023-10-04)
エクセル試験2：所得税の計算｜エクセル練習問題(2023-10-04)
エクセル試験1：曜日別の平均客単価｜エクセル練習問題(2023-10-04)
列全体を指定する時のRangeとColumnsの違い｜ツイッター出題回答 (2023-09-24)
シートのActiveXチェックボックスの指定方法｜ツイッター出題回答 (2023-09-24)
ByRef引数の型が一致しません。｜ツイッター出題回答 (2023-09-22)
シートコピー後のアクティブシートは何か｜ツイッター出題回答 (2023-09-19)
Excel関数の引数を省略した場合について｜ツイッター出題回答 (2023-09-14)
セル個数を返すRange.CountLargeプロパティとは｜VBA技術解説(2023-09-08)
記号を繰り返してグラフ作成（10単位で折り返す）｜ツイッター出題回答 (2023-08-28)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.RangeとCellsの使い方｜VBA入門
3.繰り返し処理（For Next)｜VBA入門
4.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
5.変数宣言のDimとデータ型｜VBA入門
6.マクロとは？VBAとは？VBAでできること｜VBA入門
7.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
8.条件分岐（IF）｜VBA入門
9.並べ替え（Sort）｜VBA入門
10.Range以外の指定方法（Cells,Rows,Columns）｜VBA入門
- ホーム
- マクロVBA入門編
- VBA100本ノック
- 72本目：ITをDXに変換（文字列操作）
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。