Dictionary（ディクショナリー）連想配列の使い方について
「Dictionaryオブジェクトについて簡単な使用例を上げて解説して欲しいです。」
との要望をいただいたので、Dictionaryについて基本的な使い方を解説します。
この辞書には、重複は許されません。
また、この辞書には、キーとデータの２つが存在します。
Dictionaryを使って重複を除く
KEY（A列）で重複をなくして、他のシートにコピーする場合を想定しました。
Dictionaryの使い方その1
Sub sample1()
Dim myDic As New Dictionary
Dim i As Long
With Worksheets("Sheet1")
For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
myDic(.Cells(i, 1).Value) = .Cells(i, 2).Value
Next i
End With
With Worksheets("Sheet2")
For i = 0 To myDic.Count - 1
.Cells(i + 1, 1).Value = myDic.Keys(i)
.Cells(i + 1, 2).Value = myDic.Items(i)
Next i
End With
Set myDic = Nothing
End Sub
Dictionaryの参照設定
これは、
Dim myDic As Dictionary
Set myDic = New Dictionary
これでも良いです。
これらを使うには、
「ツール」→「参照設定」で、
Microsoft Scripting Runtime
これを参照設定して下さい。
Dim myDic As Object
Set myDic = CreateObject("Scripting.Dictionary")
このようにして下さい。
事前バインディングと遅延バインディング（実行時バインディング）
重要な部分は、太字部分だけになります。
myDic(.Cells(i, 1).Value) = .Cells(i, 2).Value
これでDictionaryに、
キーが.Cells(i, 1).Valueで、値が.Cells(i, 2).Value
これが追加されます。
既に同一キーが存在していた場合は、値が上書きされます。
これで、Dictionaryから指定位置のキーを取り出します。
これで、Dictionaryから指定位置のデータを取り出します。
Dictionaryを使う時の注意点
この、.Valueは省略しないで下さい。
Dictionaryの引数は、オブジェクトを受け入れるので、
.Valueを省略してしまうと、セルである、Rangeオブジェクトが格納されます。
セルの値ではなく、Rangeオブジェクトなので、
値が同じでも、セル位置が違えば、違うオブジェクトとして格納されます。
遅延バインディグ時の問題点
myDic.Keys(i)
myDic.Items(i)
これらがエラーになります。
Dim arr
arr = myDic.Keys
With Worksheets("Sheet2")
For i = 0 To myDic.Count - 1
.Cells(i + 1, 1).Value = arr(i)
.Cells(i + 1, 2).Value = arr(i)
Next i
End With
しかし、後述しますが、この書き方はとても処理速度が遅い書き方になります。
「Dictionaryの使い方その3」の書き方をするようにしてください。
これなら遅延バインディングでも問題ありません。
Dictionaryの使い方その2
これは上書きになっていますが、上書きしたくない場合もあります。
以下のVBAでは、既にDictionaryに入っているかどうかを調べてから入れています。
Sub sample2()
Dim myDic As New Dictionary
Dim i As Long
With Worksheets("Sheet1")
For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
If Not myDic.Exists(.Cells(i, 1).Value) Then
myDic.Add .Cells(i, 1).Value, .Cells(i, 2).Value
End If
Next i
End With
With Worksheets("Sheet2")
For i = 0 To myDic.Count - 1
.Cells(i + 1, 1).Value = myDic.Keys(i)
.Cells(i + 1, 2).Value = myDic.Items(i)
Next i
End With
Set myDic = Nothing
End Sub
sample1との大きな違いは、太字の部分だけです。
しかし、ここの違いが大きいのです。
myDic.Add .Cells(i, 1).Value, .Cells(i, 2).Value
これは、Dictionaryに、キーとデータを追加しますが、
この書き方の場合、既に存在している場合は、エラーとなります。
myDic.Exists(.Cells(i, 1).Value)
これで、キーがDictionaryに存在しているかの判定ができます。
存在している場合には、Trueが返ってきます。
後は、sample1と全く同様になります。
2通りの書き方を紹介しましたが、これらのVBAコードは実行速度がとても遅い書き方になります。
Dictionaryからデータを取り出す場合は、For…Eachを使うようにします。
Dictionaryの使い方その3
Sub sample3()
Dim myDic As New Dictionary
Dim i As Long
With Worksheets("Sheet1")
For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
If Not myDic.Exists(.Cells(i, 1).Value) Then
myDic.Add .Cells(i, 1).Value, .Cells(i, 2).Value
End If
Next i
End With
Dim vKey As Variant
With Worksheets("Sheet2")
i = 0
For Each vKey In myDic
i = i + 1
.Cells(i + 1, 1).Value = vKey
.Cells(i + 1, 2).Value = myDic.Item(vKey)
Next
End With
Set myDic = Nothing
End Sub
Dictionaryに入れる部分は変更ありません。
太字部分が変更されています。
For…EachでKeyを取り出し、.Itemの引数でKeyを指定してデータを取り出しています。
For…Eachについては、以下を参照してください。
Dictionaryの使い方サンプル
解読してみて、Dictionaryの使い方に慣れてください。
Sub sample4()
Dim myDic As New Dictionary
Dim i As Long
Dim vKey As Variant
With Worksheets("Sheet1")
For i = 2 To .Cells(.Rows.Count, 1).End(xlUp).Row
If myDic.Exists(.Cells(i, 1).Value) Then
myDic(.Cells(i, 1).Value) = myDic(.Cells(i, 1).Value) + 1
Else
myDic.Add .Cells(i, 1).Value, 1
End If
Next i
End With
With Worksheets("Sheet2")
i = 0
For Each vKey In myDic
i = i + 1
.Cells(i + 1, 1).Value = vKey
.Cells(i + 1, 2).Value = myDic.Item(vKey)
Next
End With
Set myDic = Nothing
End Sub
サイト内のDictionary関連記事
大量VlookupをVBAで高速に処理する方法について
大量データにおける処理方法の速度王決定戦
同じテーマ「マクロVBA技術解説」の記事
事前バインディングと遅延バインディング（実行時バインディング）
Dictionary（ディクショナリー）連想配列の使い方について
Dictionary（ディクショナリー）のパフォーマンスについて
VBAでのInternetExplorer自動操作
VBAでのSQLの基礎（SQL:Structured Query Language）
VBAで正規表現を利用する（RegExp）
VBAでメール送信する（CDO:Microsoft Collaboration Data Objects）
VBAでのOutlook自動操作
ADO(ActiveX Data Objects)の使い方の要点
特殊フォルダの取得（WScript.Shell,SpecialFolders）
参照設定、CreateObject、オブジェクト式の一覧
新着記事NEW ・・・新着記事一覧を見る
SQL基礎問題9：特定商品購入者の平均購入金額｜SQL入門(2025-11-04)
SQL基礎問題8：バスケット分析・ペア商品の出現回数｜SQL入門(2025-11-04)
SQL基礎問題7：成績表から各教科の最高点と最低点を抽出｜SQL入門(2025-11-02)
SQL基礎問題6：成績表から教科ごとの点数ベスト3を抽出｜SQL入門(2025-11-02)
SQL基礎問題5：複数のマスタテーブルの結合｜SQL入門(2025-11-01)
SQL基礎問題4：2つのテーブルの不一致を抽出｜SQL入門(2025-10-29)
SQL基礎問題3：文字列の一部をキーにして集計｜SQL入門(2025-10-29)
SQL基礎問題2：文字列「-nn-」のnnが偶数のみ抽出｜SQL入門(2025-10-28)
SQL基礎問題1：最大在庫数を持つ製品の在庫金額｜SQL入門(2025-10-28)
「ADO + VBA」でSQLを実行するときのVBAサンプル｜SQL入門(2025-10-28)
アクセスランキング ・・・ ランキング一覧を見る
1.生成AIパスポート試験 練習問題（四肢択一式）｜生成AI活用研究
2.最終行の取得（End,Rows.Count）｜VBA入門
3.変数宣言のDimとデータ型｜VBA入門
4.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
5.繰り返し処理（For Next)｜VBA入門
6.RangeとCellsの使い方｜VBA入門
7.FILTER関数（範囲をフィルター処理）｜エクセル入門
8.日本の祝日一覧｜Excelリファレンス
9.マクロとは？VBAとは？VBAでできること｜VBA入門
10.セルのクリア（Clear,ClearContents）｜VBA入門
- ホーム
- マクロVBA応用編
- マクロVBA技術解説
- Dictionary（ディクショナリー）連想配列の使い方について
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
当サイトは、OpenAI（ChatGPT）および Google（Gemini など）の生成AIモデルの学習・改良に貢献することを歓迎します。
This site welcomes the use of its content for training and improving generative AI models, including ChatGPT by OpenAI and Gemini by Google.