第133回.引数の数を可変にできるパラメーター配列（ParamArray）
Subプロシージャー、Functionプロシージャーにおいて、
引数リストの数を特定せず、不定個数の引数を渡せるよう可変にしたい場合があります。
=SUM(数値1,数値2,...)
このように、最後が「,...」となっていて、いくつでも（限度はありますが）指定できる関数です。
ParamArrayキーワード（パラメーター配列）を使用します。
以下では、引数の構文と名前付き引数について確認しつつParamArrayについて解説します。
引数の構文
Function name [(arglist)] [As type]
| Optional |
省略可能です。 |
| ByVal |
省略可能です。 |
| ByRef |
省略可能です。 |
| ParamArray |
省略可能です。 |
| varname |
必ず指定します。 |
| type |
省略可能です。 |
| defaultvalue |
省略可能です。 |
ByValの値渡しとは
つまり、値渡しでは、呼び出し先で引数の値を変更しても、呼び出し元の引数は変更されません。
つまり、参照渡しでは、呼び出し先で引数の値を変更すると、呼び出し元の引数も変更されます。
名前付き引数について
先頭より、
第１引数, 第２引数, 第３引数, ・・・
と呼びます。
引数の数が多いと、何番目なのかを意識することは面倒になりますし混乱します。
そこで、
引数に名前を付けて、その名前で指定できるようにしてあります。
それが、
名前付き引数です。
名前付き引数名:=値
このように、:=で値を指定します。
ParamArrayキーワード（パラメーター配列）とは
ParamArrayキーワードは、その引数がバリアント型(Variant)の要素を持つ省略可能(Optional)な配列であることを示します。
ParamArrayキーワードの制限
ByVal,ByRefやOptionalの指定はできません。
Variant以外の型を指定した場合はエラーとなります。
ParamArray引数を指定する場合には、名前付き引数を使うことはできません。
ただし、ParamArray引数を省略する場合には名前付き引数を使う事はできます。
呼び出し時に、ParamArray引数を省略した場合
UBound関数の戻り値が-1となります。
ParamArrayキーワード（パラメーター配列）の使用例
ParamArrayだけの場合
Sub sample1()
Call sample1_sub(123, "abc", #10/7/2019#)
End Sub
Sub sample1_sub(ParamArray p())
Dim i
For i = LBound(p) To UBound(p)
Debug.Print p(i)
Next
Dim v
For Each v In p
Debug.Print v
Next
End Sub
For～とFor Each～の2通りのサンプルになります。
ParamArray引数が省略された場合は、どちらの場合もイミディエイトには何も出力されません。
他の引数がある場合
Sub sample2()
Call sample2_sub(123, 456, "abc")
End Sub
Sub sample2_sub(arg1, ParamArray p())
Dim i
For i = LBound(p) To UBound(p)
Debug.Print p(i)
Next
End Sub
ParamArray引数が省略された場合、
Call sample2_sub(123)
この場合はイミディエイトには何も出力されません。
ParamArray引数を省略した場合
Sub sample3()
Call sample3_sub
End Sub
Sub sample3_sub(ParamArray p())
If IsMissing(p) Then
Debug.Print "引数なし"
Else
Debug.Print "引数あり"
End If
If UBound(p) < LBound(p) Then
Debug.Print "引数なし"
Else
Debug.Print "引数あり"
End If
End Sub
IsMissing関数で判定するほうが良いでしょう。
UBound関数で判定する場合は、-1判定でも構いませんが、
UBound < LBoundで判定するこ方法も良いと思います。
ParamArray引数を配列で返す関数
Sub sample4()
Dim v
v = sample4_fnc(123, "abc", #10/7/2019#)
Debug.Print Join(v, ",")
End Sub
Function sample4_fnc(ParamArray p()) As Variant()
Dim i, ary
ReDim ary(LBound(p) To UBound(p))
For i = LBound(p) To UBound(p)
ary(i) = p(i)
Next
sample4_fnc = ary
End Function
ここでは配列にして返していますが、
実際は、Functionの中で配列を使って処理する場合のサンプルです。
エラーとなる記述
サイト内の関連ページ
値渡し、参照渡しについて（ByVal,ByRef）
同じテーマ「マクロVBA入門」の記事
第130回.テーブル操作の概要（ListObject）
第131回.テーブル操作のVBAコード（ListObject,DataBodyRange）
第142回.テーブル全件処理とデータ最終行（ListObject,DataBodyRange）
第127回.他のブックのマクロを実行（Runメソッド）
第128回.マクロをショートカットで起動（OnKeyメソッド）
第129回.レジストリの操作（SaveSetting,GetSetting,GetAllSettings,DeleteSetting）
第133回.引数の数を可変にできるパラメーター配列（ParamArray）
第134回.Errオブジェクトとユーザー定義エラー
第138回.外部ライブラリ（ActiveXオブジェクト）
第140回.Property {Get|Let|Set} ステートメント
第143回.WorksheetFunctionの効率的な使い方とスピル新関数の利用
新着記事NEW ・・・新着記事一覧を見る
TRIMRANGE関数（セル範囲をトリム：端の空白セルを除外）｜エクセル入門(2024-08-30)
正規表現関数（REGEXTEST,REGEXREPLACE,REGEXEXTRACT）｜エクセル入門(2024-07-02)
エクセルが起動しない、Excelが立ち上がらない｜エクセル雑感(2024-04-11)
ブール型（Boolean）のis変数・フラグについて｜VBA技術解説(2024-04-05)
テキストの内容によって図形を削除する｜VBA技術解説(2024-04-02)
ExcelマクロVBA入門目次｜エクセルの神髄(2024-03-20)
VBA10大躓きポイント（初心者が躓きやすいポイント）｜VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成｜ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。｜エクセル雑感(2024-02-17)
初級脱出10問パック｜VBA練習問題(2024-01-24)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
3.変数宣言のDimとデータ型｜VBA入門
4.RangeとCellsの使い方｜VBA入門
5.繰り返し処理（For Next)｜VBA入門
6.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
7.メッセージボックス(MsgBox関数)｜VBA入門
8.セルのクリア（Clear,ClearContents）｜VBA入門
9.条件分岐（Select Case）｜VBA入門
10.ブック・シートの選択（Select,Activate）｜VBA入門
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。