VBA100本ノック 78本目:グラフのデータ範囲拡張
シートの複数のグラフに対して、データ範囲を自動拡張する問題です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。
出題
シートには複数のグラフがあります。
シートの全グラフのデータの範囲を一括で変更します。
データ範囲の下に追加された行をグラフのデータ範囲に追加してください。
※画像では2021/01を追加(B1:C10をB1:C11)します。
※シートは任意


https://excel-ubara.com/vba100sample/VBA100_78.xlsm
https://excel-ubara.com/vba100sample/VBA100_78.zip
VBA作成タイム
この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。
他の人の回答および解説を見て、書いたVBAを見直してみましょう。
頂いた回答
解説
グラフには系列がありSeriesCollectionで取得します。
SeriesCollectionのFormulaでデータ範囲を取得できます。
このデータ範囲をCurrentRegionの最終行まで広げるようにしました。
サンプルは1系列でしたが複数系列にも対応してみました。
Sub VBA100_78_01()
Dim ws As Worksheet
Set ws = ActiveSheet
Dim cht As ChartObject, src As Series, aryFormula() As String
For Each cht In ws.ChartObjects
For Each src In cht.Chart.SeriesCollection
aryFormula = Split(src.Formula, ",")
aryFormula(1) = getNewRegion(aryFormula(1))
aryFormula(2) = getNewRegion(aryFormula(2))
src.Formula = Join(aryFormula, ",")
Next
Next
End Sub
Function getNewRegion(ByVal sFormula As String) As String
Dim rngOld As Range, rngNew As Range
Set rngOld = Application.Range(sFormula)
Set rngNew = rngOld.CurrentRegion
Set rngNew = rngOld.Resize(rngNew.Item(rngNew.Count).Row - rngOld.Item(1).Row + 1)
getNewRegion = rngNew.Address(external:=True)
End Function
そもそも元のセル範囲が分かれば、単純にCurrentRegionから取得したRnageをSetSourceDataに入れるだけで済んでしまいます。
これについては記事補足に掲載しました。
補足
実際にそれを使って回答された方も複数おられました。
このタイトルのセル範囲を基準にしてデータ範囲を取得できるように配置しておけば、難しい系列の数式解析などする必要は無くなります。
Sub VBA100_78_02()
Dim ws As Worksheet: Set ws = ActiveSheet
Dim cht As ChartObject, src As Series, rng As Range
For Each cht In ws.ChartObjects
Set rng = Application.Range(cht.Chart.ChartTitle.Formula)
Set rng = rng.CurrentRegion
Set rng = Intersect(rng, rng.Offset(, 1))
Call cht.Chart.SetSourceData(rng)
Next
End Sub
今回のサンプルではタイトルとデータ部分が隣接していましたが、位置関係さえ決まっていれば離れていても構いません。
Offset等でずらして範囲取得するようにすれば良いでしょう。
つまり、単純な範囲設定でグラフを作成できるような元表を用意することが大切だという事になります。
サイト内関連ページ
同じテーマ「VBA100本ノック」の記事
75本目:ログインフォームの作成
76本目:ボタンの表示名の位置へ移動
77本目:シート挿入イベント
78本目:グラフのデータ範囲拡張
79本目:Wordにセル範囲を図として挿入
80本目:読み取り専用で保存できないブックにする
81本目:全フィルターの絞り込解除
81本目:全フィルターの絞り込解除
82本目:ブックのドキュメントプロパティを取得
83本目:請求書を作成してPDF出力
84本目:ブックの自動バックアップ
新着記事NEW ・・・新着記事一覧を見る
エクセル試験3:月間の所定労働時間|エクセル練習問題(2023-10-04)
エクセル試験2:所得税の計算|エクセル練習問題(2023-10-04)
エクセル試験1:曜日別の平均客単価|エクセル練習問題(2023-10-04)
列全体を指定する時のRangeとColumnsの違い|ツイッター出題回答 (2023-09-24)
シートのActiveXチェックボックスの指定方法|ツイッター出題回答 (2023-09-24)
ByRef引数の型が一致しません。|ツイッター出題回答 (2023-09-22)
シートコピー後のアクティブシートは何か|ツイッター出題回答 (2023-09-19)
Excel関数の引数を省略した場合について|ツイッター出題回答 (2023-09-14)
セル個数を返すRange.CountLargeプロパティとは|VBA技術解説(2023-09-08)
記号を繰り返してグラフ作成(10単位で折り返す)|ツイッター出題回答 (2023-08-28)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.繰り返し処理(For Next)|VBA入門
4.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.マクロとは?VBAとは?VBAでできること|VBA入門
7.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
8.条件分岐(IF)|VBA入門
9.並べ替え(Sort)|VBA入門
10.Range以外の指定方法(Cells,Rows,Columns)|VBA入門
- ホーム
- マクロVBA入門編
- VBA100本ノック
- 78本目:グラフのデータ範囲拡張
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。