VBAで写真の撮影日時や音楽動画の長さを取得する

公開日：2020-01-23　最終更新日：2020-01-23

VBAで写真の撮影日時や音楽動画の長さを取得する

写真の撮影日時、音楽や動画の再生時間、これらをVBAで取得します。

写真や音楽、動画をフォルダにまとめて入れている人は多いのではないでしょうか。
しかし、なかなかちゃんと管理できていなかったりしませんか。
私がそうなんですけど・・・

エクセルでこれらのファイル一覧を作成するときに役立つように、
VBAでより詳しい情報を取得する方法について説明します

VBAで写真の撮影日時を取得


  
    
      Sub PrintExtendedProperty()

      　　Dim sPath As String

      　　sPath = ThisWorkbook.Path & "\Camera\"

      　　

      　　Dim sh As New Shell32.Shell

      　　Dim shFolder As Folder3

      　　Dim shFile As FolderItem

      　　Set shFolder = sh.Namespace(sPath)

      　　

      　　Dim fso As New FileSystemObject

      　　Dim fsoFile As File

      　　For Each fsoFile In fso.GetFolder(sPath).Files

      　　　　Set shFile = shFolder.ParseName(fsoFile.Name)

      　　　　Debug.Print shFile.Name

      　　　　Debug.Print shFile.ExtendedProperty("System.Photo.DateTaken")

      　　　　Debug.Print shFile.ExtendedProperty("System.Photo.CameraModel")

      　　Next

      End Sub

参照設定

Microsoft Shell Controls And Automation
Microsoft Scripting

Shell.ApplicationとFileSystemObjectです。
参照設定しない場合の記述については、この後で掲載しています。

Shell.Namespaceメソッド

指定されたフォルダーのFolderオブジェクトを作成して返します。

Folder.ParseNameメソッド

FolderItemオブジェクトを作成して返します。

このVBAを実行すると、イミディエイトウインドウに、
ファイル名、撮影日時、モデルが出力されます。

撮影日時だけならこれで構いませんが、他の情報も欲しいとなったら・・・
問題は、
shFile.ExtendedProperty("System.Photo.DateTaken")
この引数の文字列の部分です。
対応するこの文字列を調べるのが大変です。
WEBで少々調べましたが、都合の良い一覧は見つかりませんでした。
見つかったとしても、使うたびに一覧を見なければなりません。
もう少し汎用的に使える方法が欲しいところです。

全てのプロパティを取得するVBA

GetDetailsOfを使い、インデックスで取得します。


  
    
      Function getExtendedProperty(ByVal aFilePath As String) As Variant()

      　　Dim rtnAry() As Variant

      　　ReDim rtnAry(500, 1)

      　　

      　　Dim fso As Object

      　　Set fso = CreateObject("Scripting.FileSystemObject")

      　　

      　　Dim sh As Object

      　　Set sh = CreateObject("Shell.Application")

      　　Dim shFolder As Object

      　　Dim shFile As Object

      　　Set shFolder = sh.Namespace(fso.GetParentFolderName(aFilePath))


      　　Dim i As Long

      　　Set shFile = shFolder.ParseName(fso.GetFileName(aFilePath))

      　　'以下でも良い

      　　'Set shFile = shFolder.Items.Item(fso.GetFileName(aFilePath))

      　　For i = 0 To 500

      　　　　rtnAry(i, 0) = shFolder.GetDetailsOf(Nothing, i)

      　　　　rtnAry(i, 1) = shFolder.GetDetailsOf(shFile, i)

      　　Next

      　　getExtendedProperty = rtnAry

      End Function

汎用的に使えるように、遅延バインディングにしています。

・バインディングとは・事前バインディング・遅延バインディング（実行時バインディング）・実装（VBA記述）の違い・事前バインディングの利点

Folder.GetDetailsOfメソッド

フォルダー内のアイテムに関する詳細を取得します。
取得する情報を指定する整数値を引数に指定します。

2次元配列を返す関数Functionです。
手元のWindows10での確認では、プロパティは321まで使われていました。
これはOS等の環境によって変わってくるはずです。
上記VBAでは、サンプルとして無条件で500までの配列で返しています。
簡単に実行できますので、実際に試してみてください。

全てのプロパティを取得するVBAの使用例


  
    
      Sub sample()

      　　Dim rtnAry() As Variant

      　　rtnAry = getExtendedProperty("ファイルのフルパス\ファイル名")

      　　With ActiveSheet

      　　　　.Cells.Clear

      　　　　.Range("A1").Resize(UBound(rtnAry, 1) + 1, UBound(rtnAry, 2) + 1) = rtnAry

      　　End With

      End Sub

A列にプロパティ名、B列にプロパティ値が出力されます。

写真の撮影日時

Androidスマホで撮影した写真です。

音楽・動画の長さ

これはスマホに入っていた、ある歌手のMVのmp4です。
再生時間は4分34秒です。

VBAで撮影日時や音楽動画の長さ取得の最後に

ファイルのプロパティには実に多くの情報が入っています。
もちろん、保存されている情報は撮影する機器によって変わってきます。
露出や絞り等々、カメラが対応していればこれらの情報がいろいろと入っていますので、アルバム整理等に役立つと思います。
筆者はあまりこの辺りの事は詳しくありませんので、あくまでVBAの紹介だけをしました。

同じテーマ「マクロVBA技術解説」の記事

VBAにおける変数のメモリアドレスについて

・メモリアドレスを取得する関数とメモリコピーのWindowsAPI ・メモリアドレスを確認するために使用したVBA ・文字列型Stringのメモリアドレス・Integer, Long, Single, Double, Dateのメモリアドレス・Variantのメモリアドレス・配列のメモリアドレス・オブジェクトのメモリアドレス・ByRef,ByValのメモリアドレス

Evaluateメソッド（文字列の数式を実行します）

・Evaluateメソッドの構文・Evaluateメソッドの解説と使用例・Evaluateメソッドの最後に

Rangeオブジェクトの論理演算（差集合と排他的論理和）

・集合について・Rangeオブジェクトの論理演算のVBAについて・和集合：Unionメソッド・積集合：Intersectメソッド・補集合・差集合・排他的論理和・Rangeオブジェクトの論理演算VBAの使い方とテスト

VBAで写真の撮影日時や音楽動画の長さを取得する
VBAでWindowsMediaPlayerを使い動画再生する

・ワークシートにWindowsMediaPlayerを事前に追加・ワークシートにWindowsMediaPlayerコントロールを動的に追加・ユーザーフォームにWindowsMediaPlayerを事前に追加・ユーザーフォームにWindowsMediaPlayerを動的に追加・簡単に動画再生するだけなら・VBAでの動画再生の最後に

VBAでWEBカメラ操作する

・ActiveMovie Windowを起動する・メインのユーザーフォーム・WEBカメラを選択するユーザーフォーム・上記ユーザーフォームの使い方・APIを使いキャプチャをとる・VBAでWEBカメラ操作の最後に

VBAで電光掲示板を作成

・東雲フォントについて・東雲フォントの追加説明・東雲フォントをシートに取得するVBA ・電光掲示板のシート構成・電光掲示板のVBA ・VBAで電光掲示板を作成の最後に

ユーザーに絶対に停止させたくない場合のVBA設定

ユーザー操作によりマクロVBAが実行中に停止させられてしまう場合があります。再実行可能であれば問題ありませんが、途中で強制停止された場合のデータ保証が出来ないと言った場合もあるでしよう。マクロ実行でも、以下のキーボード操作でVBAは停止できてしまいます。

列幅・行高をDPI取得しピクセルで指定する

・列幅・行高をピクセルで指定するVBA ・列幅・行高をピクセルで指定するVBAの使い方と解説

VBAでWMIの使い方について

・WMIを調べるときの推奨サイト・VBAでのWMI使用方法・WMIにはどんなものがあるのか

アクティブシート以外のWindowを設定できるWorksheetView

・Windowオブジェクトのメソッドとプロパティ・アクティブシート以外の表示(Window)に関する設定・アクティブシート以外の表示(Window)を設定するVBA ・全ウィンドウの全シートのWorksheetViewを設定するVBA

アクセスランキング・・・ランキング一覧を見る

1.最終行の取得（End,Rows.Count）｜VBA入門
2.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
3.RangeとCellsの使い方｜VBA入門
4.ひらがな⇔カタカナの変換｜エクセル基本操作
5.繰り返し処理（For Next)｜VBA入門
6.変数宣言のDimとデータ型｜VBA入門
7.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
8.並べ替え（Sort）｜VBA入門
9.セルのクリア（Clear,ClearContents）｜VBA入門
10.Findメソッド（Find,FindNext,FindPrevious）｜VBA入門

ホーム
マクロVBA応用編
マクロVBA技術解説
VBAで写真の撮影日時や音楽動画の長さを取得する

このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。

記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。

VBA技術解説
VBAで写真の撮影日時や音楽動画の長さを取得する