VBAサンプル集
複数シートの印刷(PrintOut)

ExcelマクロVBAの実用サンプル、エクセルVBA集と解説
公開日:2013年5月以前 最終更新日:2020-04-16

複数シートの印刷(PrintOut)


複数シートをVBAで印刷する方法です。


ワークシートが「Sheet1」「Sheet2」「Sheet3」・・・があるものとします。
そのような場合に、指定のワークシートのみ印刷する場合です。

以下では、テスト実行しやすいように、
Preview:=True
これでプレピュー表示にしています。
直接印刷する場合は、この指定を消してください。
印刷についての基本は以下を参照してください。

第71回.印刷(PrintOut)
・PrintOutメソッド ・PrintOutメソッドの使用例 ・印刷時にプリンターを選択したい場合 ・印刷総ページ数の取得 ・間違った印刷を大量に行わないわない為には
第72回.印刷プレビュー(PrintPreview)
・PrintPreviewメソッド ・PrintOutメソッドの使用 ・PrintPreviewメソッドとPrintOutメソッドの使い分け

マクロの記録と同じようにArrayに固定文字で

まずは、マクロの記録と同じように、Array関数に固定シート名を指定する場合。

Sub sample1()
  Sheets(Array("Sheet1", "Sheet2", "Sheet3")).PrintOut Preview:=True
End Sub

非表示シートが含まれているとこのVBAはエラーとなります。

VBA マクロ 複数シートの印刷 PrintOut

シート名がわかっていれば、これで良いですが、シート名が不明な場合は困ります。

シートを順次印刷していく

Sub sample2()
  Dim i As Integer
  Dim ws As Worksheet
  For Each ws In ActiveWorkbook.Worksheets
    If ws.Visible = xlSheetVisible Then
      ws.PrintOut Preview:=True
    End If
  Next
End Sub

Worksheetsコレクションを使用しているので、グラフシート等のワークシート以外は対象外になります。
また、
If ws.Visible = xlSheetVisible Then
これで、表示シートだけを対象にしています。

ただし、この場合は、プリントスプールが別々になります。
共有プリンターで印刷する場合は、他の人の印刷と混ざってしまう可能性があります。

シート名の配列を作成して一括で印刷する

1つのスプールで印刷する場合です。

Sub sample3()
  Dim mySht As Variant
  Dim i As Long
  For i = 1 To Worksheets.Count
    If Worksheets(i).Visible = xlSheetVisible Then
      If IsEmpty(mySht) Then
        ReDim mySht(0)
      Else
        ReDim Preserve mySht(UBound(mySht) + 1)
      End If
      mySht(UBound(mySht)) = Worksheets(i).Name
    End If
  Next i
  If Not IsEmpty(mySht) Then
    Sheets(mySht).PrintOut Preview:=True
  End If
End Sub

配列の使い方はいろいろあります。
mySht(1 To ・・・)として、1から使用するのも良いでしょう。

mySht(UBound(mySht)) = Worksheets(i).Name

mySht(UBound(mySht)) = Worksheets(i).Index
このように変更して名前の代わりにIndexを入れても良いです。

Sheets(mySht).PrintOut
ここはSheetsでなければなりません、Worksheetsではエラーとなります。

一応、ワークシートが無かった時の判定も入れていますが、普通は不要だと思います。

Worksheet.Selectメソッド

配列を使用せずに、Selectメソッドを使う方法もあります。
シートの複数選択(Select)
・マクロの記録と同じようにArrayに固定文字で ・シート名の配列を作成する ・シートのSelectメソッドの引数にFalseを指定する ・全シートを選択するだけなら
Sub sample4()
  Dim mySht As Worksheet
  Dim FirstFlg As Boolean
  FirstFlg = True
  For Each mySht In ActiveWorkbook.Worksheets
    If mySht.Visible = xlSheetVisible Then
      If FirstFlg Then
        mySht.Select
        FirstFlg = False
      Else
        mySht.Select False
      End If
    End If
  Next
  If FirstFlg = False Then
    ActiveWindow.SelectedSheets.PrintOut Preview:=True
  End If
End Sub

Select False を使用しています。
Falseを指定することで、それまでの選択を有効に残して拡張選択しています。

ここまでのVBAでは、Forと、For Eachを使っていますが、特に使い分けしているわけではありません。
サンプルとして、2通りを例示しているにすぎませんので、承知おき下さい。

全てのシートを印刷するなら

Sub sample5()
  ActiveWorkbook.PrintOut Preview:=True
End Sub

全シートを印刷するなら、これだけで良いですね。
ただし、非表示シートが含まれているとこのVBAはエラーとなります。
上記VBAを使うには、事前に全シートを表示するようにする必要があります。

Sub sample6()
  Dim sht As Variant
  For Each sht In ActiveWorkbook.Sheets
    sht.Visible = xlSheetVisible
  Next
  ActiveWorkbook.PrintOut Preview:=True
End Sub

シートはワークシート以外(グラフシート等)もありえるので、 shtはVariantにしています。
そして、ActiveWorkbook.Sheets、これで全シートを対象としています。



同じテーマ「マクロVBAサンプル集」の記事

1行置きにする行挿入(Insert)
シートの追加・削除(Add,Delete)
シートの複数選択(Select)
複数シートの印刷(PrintOut)
重複削除してコピー(AdvancedFilter)
ブックを安全確実に開く方法(Open)
ブックを閉じる(Close)
他ブックを開いて閉じる(Open,Close)
ブックを開かずにセル値を取得(ExecuteExcel4Macro,Excel.Application)
罫線を簡単に引く(Borders,BorderAround)
マクロVBAの開始時と終了時に指定しておくべきApplicationのプロパティ


新着記事NEW ・・・新着記事一覧を見る

無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
VBAでクリップボードへ文字列を送信・取得する3つの方法|VBA技術解説(2023-12-07)
難しい数式とは何か?|エクセル雑感(2023-12-07)
スピらない スピル数式 スピらせる|エクセル雑感(2023-12-06)
イータ縮小ラムダ(eta reduced lambda)|エクセル入門(2023-11-20)
PIVOTBY関数(縦軸と横軸でグループ化して集計)|エクセル入門(2023-11-19)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.条件分岐(IF)|VBA入門
9.マクロとは?VBAとは?VBAでできること|VBA入門
10.セルのクリア(Clear,ClearContents)|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ