VBA100本ノック 43本目:CSV出力
シートの表を指定された形式でCSV出力する問題です。
ツイートでの見やすさを考慮して、ブック・シート指定等を適宜省略しています。
マクロVBAを初心者向けの基本から上級者向けの高度な内容までサンプルコードを掲載し解説しています。エクセル関数・機能・基本操作の入門解説からマクロVBAまでエクセル全般を網羅しています。
出題
出題ツイートへのリンク
#VBA100本ノック 43本目
表範囲をCSV出力してください。
・A列:yyyy-mm-dd
・B列:カンマなし整数
・C列:カンマなし小数2桁
・D列:文字列 (適宜ダブルクォートで囲む)
※画像はあくまで1例です。
CSVファイルはブックと同一フォルダに出力(SJIS)。
※出力ファイルおよびブック・シートの指定は任意
サンプルファイルです。
https://excel-ubara.com/vba100sample/VBA100_43.xlsm
https://excel-ubara.com/vba100sample/VBA100_43.zip
表範囲をCSV出力してください。
・A列:yyyy-mm-dd
・B列:カンマなし整数
・C列:カンマなし小数2桁
・D列:文字列 (適宜ダブルクォートで囲む)
※画像はあくまで1例です。
CSVファイルはブックと同一フォルダに出力(SJIS)。
※出力ファイルおよびブック・シートの指定は任意
https://excel-ubara.com/vba100sample/VBA100_43.xlsm
https://excel-ubara.com/vba100sample/VBA100_43.zip
VBA作成タイム
この下に頂いた回答へのリンクと解説を掲載しています。
途中まででも良いので、できるだけ自分でVBAを書いてみましょう。
他の人の回答および解説を見て、書いたVBAを見直してみましょう。
頂いた回答
解説
エクセルの機能としてあるものはそれを使うのが一番簡単です。
シートを別ブックに切り離して、csvで保存します。
ただし、表示形式で保存されるので、列ごとに適宜表示形式を設定してから保存します。
自力でテキスト出力するのも良いでしょう。
ただしFSOでは文字コードによってエラーになってしまうので面倒です。
Open…Printで出力すれば良いと思います。
D列の文字列は、多くの人が文字判定して"を必要な場合だけ追加していましたが、全て"で囲ってしまって不都合は無いと思うのですが、、、
FileSystemObjectでは、SJISに変換できない文字があるとエラーになってしまいます。
FSOで出力するなら、UTF-8で出力するか文字置換するかしかないと思います。
一応記事補足には文字置換してFSOで出力するVBAサンプルを掲載しましたが、あくまで参考程度のものです。
シートを別ブックに切り離して、csvで保存します。
ただし、表示形式で保存されるので、列ごとに適宜表示形式を設定してから保存します。
Sub VBA100_43_01()
Dim ws As Worksheet
Set ws = ActiveSheet
Dim wb As Workbook
ws.Copy
Set wb = ActiveWorkbook
With wb.Worksheets(1)
.Columns(1).NumberFormatLocal = "yyyy-mm-dd"
.Columns(2).NumberFormatLocal = "0"
.Columns(3).NumberFormatLocal = "0.00"
End With
Dim sFile As String
sFile = Replace(ThisWorkbook.Name, ".xlsm", ".csv")
wb.SaveAs FileName:=ThisWorkbook.Path & "\" & sFile, FileFormat:=xlCSV
wb.Close SaveChanges:=False
End Sub
ただしFSOでは文字コードによってエラーになってしまうので面倒です。
Open…Printで出力すれば良いと思います。
D列の文字列は、多くの人が文字判定して"を必要な場合だけ追加していましたが、全て"で囲ってしまって不都合は無いと思うのですが、、、
Sub VBA100_43_02()
Dim ws As Worksheet
Set ws = ActiveSheet
Dim sFile As String, intFree As Integer
sFile = Replace(ThisWorkbook.Name, ".xlsm", ".csv")
intFree = FreeFile
Open ThisWorkbook.Path & "\" & sFile For Output As intFree
Dim ary, i As Long
ary = ws.Range("A1").CurrentRegion
Print #1, Join(Array(ary(1, 1), ary(1, 1), ary(1, 1), ary(1, 1)), ",")
For i = LBound(ary, 1) + 1 To UBound(ary, 1)
Print #1, Format(ary(i, 1), "yyyy-mm-dd") & "," & _
Format(ary(i, 2), "0") & "," & _
Format(ary(i, 3), "0.00") & "," & _
"""" & Replace(ary(i, 4), """", """""") & """"
Next
Close intFree
End Sub
FSOで出力するなら、UTF-8で出力するか文字置換するかしかないと思います。
一応記事補足には文字置換してFSOで出力するVBAサンプルを掲載しましたが、あくまで参考程度のものです。
補足
FileSystemObject+TextStreamでは、SJISに変換できない文字があるとエラーになってしまいます。
UTF-8で出力するか、文字置換するかしかないと思います。
以下は、簡易的にAsc関数の結果で判定して置換しています。
あくまで参考程度に。
UTF-8で出力するか、文字置換するかしかないと思います。
以下は、簡易的にAsc関数の結果で判定して置換しています。
あくまで参考程度に。
Sub VBA100_43_03()
Dim ws As Worksheet
Set ws = ActiveSheet
Dim fso As New Scripting.FileSystemObject
Dim ts As TextStream, sFile As String
sFile = Replace(ThisWorkbook.Name, ".xlsm", ".csv")
Set ts = fso.CreateTextFile(FileName:=sFile, Overwrite:=True)
Dim ary, i As Long
ary = ws.Range("A1").CurrentRegion
ts.WriteLine Join(Array(ary(1, 1), ary(1, 1), ary(1, 1), ary(1, 1)), ",")
For i = LBound(ary, 1) + 1 To UBound(ary, 1)
ts.WriteLine Format(ary(i, 1), "yyyy-mm-dd") & "," & _
Format(ary(i, 2), "0") & "," & _
Format(ary(i, 3), "0.00") & "," & _
"""" & Replace(ToSJIS(ary(i, 4)), """", """""") & """"
Next
ts.Close
End Sub
Function ToSJIS(ByVal argStr As String) As String
ToSJIS = argStr
Dim i As Long
For i = 1 To Len(ToSJIS)
If Asc(Mid(ToSJIS, i, 1)) = Asc(Chr(63)) Then
Mid(ToSJIS, i, 1) = Chr(63)
End If
Next
End Function
サイト内関連ページ
VBAでのCSVの扱い方まとめ
・本サイトにあるCSV関連記事一覧 ・CSVの読込方法 ・CSVの読み込み方法(改) ・CSVの読み込み方法(改の改) ・CSVの読み込み方法(ジャグ配列) ・CSVの読み込み方法(ジャグ配列)(改) ・CSVの出力(書き出し)方法 ・UTF-8でCSVの読み書き(ADODB.Stream) ・ADOでCSVの読み込み(SQL)
CSVの読み込み方法・もっとも簡単かつ良くあるCSV読み込みVBAコード ・「,」「"」に対応したCSV読み込みVBAコード ・CSVをExcelブックとして開くVBA ・クエリーテーブルを使ったCSV読み込みVBAコード ・その他のCSV読み込み方法
CSVの読み込み方法(改)実施したいこと ・ファイル名を指定し、形式をカンマ区切り、文字列で開く、その際、改行コードLF、CRLF、CRいずれにも対応、セル内の","や改行についてはカラムで区切らない。掲示板で上記のリクエストを頂きました。ということで、対応ロジックを書いてみました。
CSVの読み込み方法(改の改)・CSVの形式について ・CSV読み込みVBAコード ・配列を使ってシートにまとめて出力する場合 ・QueryTablesを使ったCSV読み込みVBAコード ・本サイトにあるCSV関連記事一覧
CSVの読み込み方法(ジャグ配列)・CSVの読み込み方法(改の改)での予告 ・CSV読み込みでのジャグ配列の使いどころ ・CSV読み込みVBAコード:ジャグ配列バージョン ・最後に ・本サイトにあるCSV関連記事一覧
CSVの出力(書き出し)方法・エクセルの機能をそのまま利用します ・直接CSVを出力 ・本サイトにあるCSV関連記事一覧
UTF-8でCSVの読み書き(ADODB.Stream)・アクティブシートの内容をUTF-8でCSV出力します ・UTF-8のCSVを読込、シートに出力します ・ADODB.Streamのメソッドとプロパティ ・本サイトにあるCSV関連記事一覧
マクロでShift_JIS文字コードか判定する・文字コードについて ・UnicodeにあってShift_JISにない文字の具体例 ・シート構成 ・配列数式での判定 ・Shift_JIS文字コードか判定するマクロVBA全コード ・最後に
同じテーマ「VBA100本ノック」の記事
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
41本目:暗算練習アプリ・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
42本目:データベース形式に変換・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
43本目:CSV出力44本目:全テーブル一覧作成
・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
45本目:テーブルに列追加・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
46本目:名前定義に使える文字・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
47本目:Window操作・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
48本目:配列と数値型・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
49本目:条件付き書式の判定・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
50本目:トリボナッチ数列・出題 ・頂いた回答 ・解説 ・補足 ・サイト内関連ページ
新着記事NEW ・・・新着記事一覧を見る
ブール型(Boolean)のis変数・フラグについて|VBA技術解説(2024-04-05)
テキストの内容によって図形を削除する|VBA技術解説(2024-04-02)
ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得(End,Rows.Count)|VBA入門
2.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
3.RangeとCellsの使い方|VBA入門
4.ひらがな⇔カタカナの変換|エクセル基本操作
5.繰り返し処理(For Next)|VBA入門
6.変数宣言のDimとデータ型|VBA入門
7.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
8.並べ替え(Sort)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.Findメソッド(Find,FindNext,FindPrevious)|VBA入門
- ホーム
- マクロVBA入門編
- VBA100本ノック
- 43本目:CSV出力
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。