文字列のプロパティ名でオブジェクトを操作する方法
ツイッターで拝見したお題で、プロパティ名を引数の文字列で指定する方法についての参考VBAです。
例えば条件付き書式は、
Range → FormatConditions → FormatConditions(1) → Interior → Color
オブジェクトをこのように辿りますが、
"FormatConditions"、"Interior"、"Color"
これらを文字列で指定できるようにします。
CallByName関数
| 引数 | 内容 | |||||||||||||||
| object | 必ず指定します。 バリアント型およびオブジェクト型のいずれかを指定できます。 この関数の実行対象となるオブジェクトの名前を指定します。 |
|||||||||||||||
| procname | 必ず指定します。 バリアント型および文字列型のいずれかを指定できます。 オブジェクトのプロパティ名およびメソッド名を含む文字列式を指定します。 |
|||||||||||||||
| calltype | 必ず指定します。 定数値を指定します。 呼び出されるプロシージャの種類を表すvbCallTypeのメンバを指定します。
|
|||||||||||||||
| args() | 省略可能です。 バリアント型および配列を指定できます。 |
戻り値は、実行したメソッドまたはプロパティの取得値になります。
第1引数はobjectなので、標準モジュールのプロシージャーをCallByName関数で実行することはできません。
使用例
Propertyについて
第140回.Property {Get|Let|Set} ステートメント｜VBA入門
文字列のプロパティ名でオブジェクトを操作するVBAサンプル
'CallByNameを使って文字列のプロパティ名でオブジェクトを取得
Property Get CustomProperty(aObj, aProperty)
On Error Resume Next
Set CustomProperty = CallByName(aObj, aProperty, VbGet)
If Err.Number = 0 Then Exit Property
CustomProperty = CallByName(aObj, aProperty, VbGet)
End Property
'Let Propertyの最後の引数が設定する値になります
Property Let CustomProperty(aObj, aProperty, aValue)
CallByName aObj, aProperty, VbLet, aValue
End Property
用意するものはこの2つのプロパテイです。
置き場所は何処でも良いですが、標準モジュールで良いでしょう。
これはオブジェクトと単一値（スカラー値）の両方に対応しています。
単一値のプロパテイへの値の設定と取得です。
Sub sample1()
Dim rng: Set rng = Range("A1")
CustomProperty(rng, "Value") = 99
MsgBox CustomProperty(rng, "Value")
End Sub
次は、オブジェクトの階層が少し複雑になっているプロパティを扱うサンプルになります。
条件付き書式のオブジェクトを順に辿ります。
Range → FormatConditions → FormatConditions(1) → Interior → Color
Sub sample()
Dim rng: Set rng = Range("A1")
'サンプルとして条件付き書式を設定
With rng.FormatConditions
.Delete
With .Add(Type:=xlExpression, Formula1:="=A1=1")
.Interior.Color = 255
End With
End With
'FormatConditionsコレクションを取得
Dim obj1: Set obj1 = CustomProperty(rng, "FormatConditions")
'コレクションのIndexを指定してFormatConditionを特定
Dim obj2: Set obj2 = obj1(1)
'FormatConditionのInteriorオブジェクトを取得
Dim obj3: Set obj3 = CustomProperty(obj2, "Interior")
'Interiorオブジェクトの"Color"にvbBlueを設定
CustomProperty(obj3, "Color") = vbBlue
End Sub
あまり実用性があるとも思えませんが、
CallByName
Property
これらを理解する学習素材として取り組んでみてもよいかもしれません。
同じテーマ「マクロVBA技術解説」の記事
Select Caseでの短絡評価（ショートサーキット）の使い方
RangeオブジェクトのFor EachとAreasについて
画像が行列削除についてこない場合の対処
新関数SORTBYをVBAで利用するラップ関数を作成
LAMBDA以降の新関数はVBAで使えるか
数字（1～50）を丸付き数字に変換するVBA
文字列のプロパティ名でオブジェクトを操作する方法
OneDrive使用時のThisWorkbook.Pathの扱い方
セル個数を返すRange.CountLargeプロパティとは
画像「セルに配置」のVBAについて（365の新機能）
VBAでクリップボードへ文字列を送信・取得する3つの方法
新着記事NEW ・・・新着記事一覧を見る
セル数式における「再帰」の必要性｜エクセル雑感(2025-11-10)
掛け算(*)を使わない掛け算｜足し算(+)を使わない足し算｜エクセル関数応用(2025-11-10)
配列を自在に回転させる数式｜エクセル関数応用(2025-11-09)
非正規化（カンマ区切り）の結合と集計：最適な手法は？｜エクセル雑感(2025-11-06)
SQL基礎問題10：非正規化（カンマ区切り）の結合と集計｜SQL入門(2025-11-06)
SQL基礎問題9：特定商品購入者の平均購入金額｜SQL入門(2025-11-04)
SQL基礎問題8：バスケット分析・ペア商品の出現回数｜SQL入門(2025-11-04)
SQL基礎問題7：成績表から各教科の最高点と最低点を抽出｜SQL入門(2025-11-02)
SQL基礎問題6：成績表から教科ごとの点数ベスト3を抽出｜SQL入門(2025-11-02)
SQL基礎問題5：複数のマスタテーブルの結合｜SQL入門(2025-11-01)
アクセスランキング ・・・ ランキング一覧を見る
1.生成AIパスポート試験 練習問題（四肢択一式）｜生成AI活用研究
2.最終行の取得（End,Rows.Count）｜VBA入門
3.変数宣言のDimとデータ型｜VBA入門
4.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
5.繰り返し処理（For Next)｜VBA入門
6.RangeとCellsの使い方｜VBA入門
7.FILTER関数（範囲をフィルター処理）｜エクセル入門
8.日本の祝日一覧｜Excelリファレンス
9.マクロとは？VBAとは？VBAでできること｜VBA入門
10.セルのクリア（Clear,ClearContents）｜VBA入門
- ホーム
- マクロVBA応用編
- マクロVBA技術解説
- 文字列のプロパティ名でオブジェクトを操作する方法
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。
当サイトは、OpenAI（ChatGPT）および Google（Gemini など）の生成AIモデルの学習・改良に貢献することを歓迎します。
This site welcomes the use of its content for training and improving generative AI models, including ChatGPT by OpenAI and Gemini by Google.