スピルのゴーストの範囲を選択するVBA
ツイッターで出題したVBAに関する問題です。
数式を入力したセルから結果があふれて隣接したセルにも出力されるのがスピルです。
スピルについての詳細は以下を参照してください。
スピルのゴースト（あふれた先）の範囲だけを選択するVBAを作成するお題です。
出題ツイート
https://twitter.com/yamaoka_ss/status/1716718194067730828
指定シートの全セルを対象として、
スピルのゴースト（あふれた先）の範囲を選択するVBAを作成してください。
※ゴーストとはスピル数式を入れたセルは除きます
解答ツイート
Function getGhost(ByVal ws As Worksheet) As Range
On Error Resume Next
Dim rngCal As Range
Set rngCal = ws.Cells.SpecialCells(xlCellTypeFormulas)
If rngCal Is Nothing Then Exit Function
On Error GoTo 0
Dim rng As Range, rngSpill As Range
Dim rngY As Range, rngX As Range
For Each rng In rngCal
Set rngY = Nothing: Set rngX = Nothing
If rng.HasSpill Then
Set rngSpill = rng.SpillingToRange
If rngSpill.Rows.Count > 1 Then
Set rngY = rngSpill.Resize(rngSpill.Rows.Count - 1).Offset(1)
End If
If rngSpill.Columns.Count > 1 Then
Set rngX = rngSpill.Resize(, rngSpill.Columns.Count - 1).Offset(, 1)
End If
Set getGhost = UnionRange(UnionRange(getGhost, rngY), rngX)
End If
Next
End Function
Function UnionRange(ByVal rng1 As Range, rng2 As Range) As Range
If Not rng1 Is Nothing And Not rng2 Is Nothing Then
Set UnionRange = Union(rng1, rng2): Exit Function
End If
If Not rng1 Is Nothing Then
Set UnionRange = rng1: Exit Function
End If
Set UnionRange = rng2: Exit Function
End Function
使い道があるかは分かりませんが、一応関数にしておきました。
SpillingToRange
この2つのプロパティが分かればVBA自体は簡単だと思います。
スピルで追加されたプロパティについては以下を参照してください。
Sub test()
Dim rng As Range
Set rng = getGhost(ActiveSheet)
If Not rng Is Nothing Then rng.Select
End Sub
SpecialCells(xlCellTypeFormulas)
これで数式のセルだけの参照で済むようにして、
HasSpill
これでスピル数式の判定、
SpillingToRange
これでスピル範囲を取得。
例えば列全体にスピル数式が及んでいるような場合ですね。
そこで、SpillingToRangeの範囲を右および下にずらしてゴーストの範囲を取得しています。
右や下にずらす前には1つサイズを小さくする必要もありますね。
後はこれらの範囲をUnionしていけば、目的のゴースト範囲が取得できます。
同じテーマ「ツイッター出題回答 」の記事
脱字メーカー（文字列から1文字削除）
リーグ表に対戦番号を振る
数列内の連続偶数のみ順序を入れ替える
ランクによりボイントを付ける（同順位はポイントを分割）
記号を繰り返してグラフ作成（10単位で折り返す）
Excel関数の引数を省略した場合について
シートコピー後のアクティブシートは何か
ByRef引数の型が一致しません。
シートのActiveXチェックボックスの指定方法
列全体を指定する時のRangeとColumnsの違い
スピルのゴーストの範囲を選択するVBA
新着記事NEW ・・・新着記事一覧を見る
イータ縮小ラムダ（eta reduced lambda）｜エクセル入門(2023-11-20)
PIVOTBY関数（縦軸と横軸でグループ化して集計）｜エクセル入門(2023-11-19)
GROUPBY関数（縦軸でグループ化して集計）｜エクセル入門(2023-11-18)
PY関数（Pythonコードをセル内で実行）｜エクセル入門(2023-11-17)
画像「セルに配置」のVBAについて（365の新機能）｜VBA技術解説(2023-11-13)
スピルのゴーストの範囲を選択するVBA｜ツイッター出題回答 (2023-10-31)
エクセル試験3：月間の所定労働時間｜エクセル練習問題(2023-10-04)
エクセル試験2：所得税の計算｜エクセル練習問題(2023-10-04)
エクセル試験1：曜日別の平均客単価｜エクセル練習問題(2023-10-04)
列全体を指定する時のRangeとColumnsの違い｜ツイッター出題回答 (2023-09-24)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.RangeとCellsの使い方｜VBA入門
3.繰り返し処理（For Next)｜VBA入門
4.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
5.変数宣言のDimとデータ型｜VBA入門
6.条件分岐（IF）｜VBA入門
7.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
8.並べ替え（Sort）｜VBA入門
9.マクロとは？VBAとは？VBAでできること｜VBA入門
10.Range以外の指定方法（Cells,Rows,Columns）｜VBA入門
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。