VBA技術解説
ドキュメントの作成者を取得(GetObject,BuiltinDocumentProperties)

ExcelマクロVBAの問題点と解決策、VBAの技術的解説
公開日:2015-04-16 最終更新日:2019-11-19

ドキュメントの作成者を取得(GetObject,BuiltinDocumentProperties)


エクスプローラーで表示される作成者を取得したいとの問い合わせを受けたので改めて確認をしました、
所有者と混同されがちですが全く別のものになります、DOSのDIRで表示できるものは所有者になります。
従ってVBAでShell.Application作成者を取得すると書かれているものは全て勘違いをしています。


作成者は、各ドキュメントが保有している属性となります。
各ドキュメントというのは、Office(Excel、Word、PowerPoint等々)と考えてもらえば結構です。
それでは、それをどうやって取得するかですが、
各アプリケーション(Excel、Word、PowerPoint等々)を開けば取得できますが、
ファイル一覧を作成するとしたら、それぞれを判定していたのでは面倒なので、
統一的な取得方法を模索することになります。

Sub sample()
  Dim i As Long
  Dim strFile As String
  Dim strPath As String
  Dim obj As Object
  
  With Application.FileDialog(msoFileDialogFolderPicker)
    .InitialFileName = "C:\"
    .AllowMultiSelect = False
    .Title = "フォルダの選択"
    If .Show = False Then
      Exit Sub
    End If
    strPath = .SelectedItems(1) & "\"
  End With
  
  Application.EnableEvents = False '起動時のOpenイベント等を停止
  On Error Resume Next 'GetObjectで取得できないファイルの対策
  strFile = Dir(strPath)
  i = 2
  Do While strFile <> ""
    Cells(i, 1) = strFile 'ファイル名
    Cells(i, 2) = FileDateTime(strPath & strFile) '更新日時
    Cells(i, 3) = FileLen(strPath & strFile) 'サイズ
    Set obj = GetObject(strPath & strFile)
    If Err.Number <> 0 Then
      'Officeのドキュメントではないということ
      Err.Clear
    Else
      Cells(i, 4).Value = obj.BuiltinDocumentProperties(3) 'Author
      Cells(i, 5).Value = obj.BuiltinDocumentProperties(7) 'Last Author
      obj.Close
    End If
    strFile = Dir()
    i = i + 1
  Loop
  Set obj = Nothing
  Application.EnableEvents = True
End Sub


アクティブシートのA列から
ファイル名、更新日時、サイズ、作成者、最終作成者
の順に出力しています。
1行目には見出しを事前に入れておいてください。
また、初期クリアしていませんので、適宜入れて下さい。


GetObjectのところで、当該のアプリケーションで開いてプロパティを取得しても良いことになります。
しかし、前述のとおり、Excel限定なら良いのですが、WordもPowerPointもあるとなると、かなり面倒になってきます。
そこで簡単かつ統一的にプロパティを取得する方法としてGetObjectを使用しています。
・GetObject関数の構文 ・GetObjectの解説 ・GetObject関数の使用例 ・GetObject関数とCreateObject関数の使い分け ・CreateObject関数
Application.EnableEvents = False
これでOpenに伴うイベント動作を停止していますが、Excel以外では有効となりません。
ですが、Excel以外でOpenイベントの入ったドキュメントもそうそうあるものではないと思いますので、通常はこれで問題ないと思います。
もし、Excel以外で、そのようなドキュメントを扱っているのなら、別途考慮してください。


BuiltinDocumentProperties
3または"Author"を引数に指定します、どちらでも同じです。
以下に一覧を掲載します。


インデックス 名称
1 Title
2 Subject
3 Author
4 Keywords
5 Comments
6 Template
7 Last author
8 Revision number
9 Application name
10 Last print date
11 Creation date
12 Last save time
13 Total editing time
14 Number of pages
15 Number of words
16 Number of characters
17 Security
18 Category
19 Format
20 Manager
21 Company
22 Number of bytes
23 Number of lines
24 Number of paragraphs
25 Number of slides
26 Number of notes
27 Number of hidden Slides
28 Number of multimedia clips
29 Hyperlink base
30 Number of characters (with spaces)
31 Content type
32 Content status
33 Language
34 Document version


沢山ありますが、実際に使われているものは限られます。
また、設定自体は存在していても使えないものもあるようです。




同じテーマ「マクロVBA技術解説」の記事

リボンを非表示、2003以前ならメニューを非表示
印刷ページ設定の余白をセンチで指定する(CentimetersToPoints)
文字列としてのプロシージャー名を起動する方法(Run,OnTime)
ドキュメントの作成者を取得(GetObject,BuiltinDocumentProperties)
画像サイズ(横x縦)の取得について
文字種(ひらがな、全半角カタカナ、半角英大文字等々)の判定
オブジェクトとプロパティの真実
オブジェクト式について
オブジェクトの探索方法(オートシェイプのTextを探して)
条件付きコンパイル(32ビット64ビットの互換性)
ドキュメントプロパティ(BuiltinDocumentProperties,CustomDocumentProperties)


新着記事NEW ・・・新着記事一覧を見る

ExcelマクロVBA入門目次|エクセルの神髄(2024-03-20)
VBA10大躓きポイント(初心者が躓きやすいポイント)|VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成|ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。|エクセル雑感(2024-02-17)
初級脱出10問パック|VBA練習問題(2024-01-24)
累計を求める数式あれこれ|エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE|エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。|エクセル雑感(2023-12-28)
VBAでクリップボードへ文字列を送信・取得する3つの方法|VBA技術解説(2023-12-07)
難しい数式とは何か?|エクセル雑感(2023-12-07)


アクセスランキング ・・・ ランキング一覧を見る

1.最終行の取得(End,Rows.Count)|VBA入門
2.RangeとCellsの使い方|VBA入門
3.セルのコピー&値の貼り付け(PasteSpecial)|VBA入門
4.繰り返し処理(For Next)|VBA入門
5.変数宣言のDimとデータ型|VBA入門
6.ブックを閉じる・保存(Close,Save,SaveAs)|VBA入門
7.並べ替え(Sort)|VBA入門
8.条件分岐(IF)|VBA入門
9.セルのクリア(Clear,ClearContents)|VBA入門
10.マクロとは?VBAとは?VBAでできること|VBA入門




このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。


記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。



このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
本文下部へ