サロゲートペアに対応した自作関数（Len,Left,Mid,Right）
ツイッターで、サロゲートペアに対応した文字列関数の話しになりました。
そして、VBA関数の、Len,Left,Mid,Right、これらは一切サロゲートペアに対応していません。
これが必要になることもほとんどないのですが、ツイッターで話したついでなので関数を自作してみました。
とりあえず作って見たので、残しておく意味でここに掲載しておくことにしました。
サロゲートペアとは
簡単に言うと、UNICODEの2文字分で1文字を表すものです。
通常2バイトで1文字のところ、4バイトで1文字になっています。
𩸽
𠮟
これらはサロゲートペア文字です。
※サロゲートペアについての詳細はネットで検索してください。
通常2バイトで1文字のところ、4バイトで1文字になっています。
𩸽
𠮟
これらはサロゲートペア文字です。
4バイトを超えるマルチバイト文字
4バイトでも足らなくて?、さらにもっと多くのバイト数を使っているものもあります。
🙇♂️
🙅♂️
今回は、これらには対応していません。
もう、ここまでくると、わけわからない・・・
🙇♂️
🙅♂️
もう、ここまでくると、わけわからない・・・
以下2通り書いてみて、どちらが良いとも言えないので、両方残すことにしました。
サロゲートペアに対応した文字列関数のVBA、その1
Function xLen(ByVal s As String) As Long
Dim i As Long, cnt As Long
i = 1: cnt = 0
Do While i <= Len(s)
If i < Len(s) Then
If isSurrogatePair(Mid(s, i, 2)) Then
i = i + 1
End If
End If
cnt = cnt + 1
i = i + 1
Loop
xLen = cnt
End Function
Function xMid(ByVal s As String, ByVal st As Long, Optional ByVal ln As Long = 0) As String
If ln = 0 Then ln = Len(s)
Dim cnt As Long
cnt = 1
Do While xLen(Left(s, cnt)) < st And cnt <= Len(s)
cnt = cnt + 1
Loop
Do While xLen(xMid) < ln And cnt <= Len(s)
xMid = xMid & Mid(s, cnt, 1)
If cnt < Len(s) Then
If isSurrogatePair(Mid(s, cnt, 2)) Then
xMid = xMid & Mid(s, cnt + 1, 1)
cnt = cnt + 1
End If
End If
cnt = cnt + 1
Loop
End Function
Function xLeft(ByVal s As String, ByVal ln As Long) As String
xLeft = xMid(s, 1, ln)
End Function
Function xRight(ByVal s As String, ByVal ln As Long) As String
xRight = xMid(s, xLen(s) - ln + 1)
End Function
Function isSurrogatePair(ByVal s As String)
Dim b() As Byte: b = s
Dim h1 As Long, h2 As Long
isSurrogatePair = False
h1 = b(0) + b(1) * 256&
h2 = b(2) + b(3) * 256&
If h1 >= &HD800& And h1 <= &HDBFF& And _
h2 >= &HDC00& And h2 <= &HDFFF& Then
isSurrogatePair = True
End If
End Function
サロゲートペアに対応した文字列関数のVBA、その2
Function xLen(ByVal s As String) As Long
Dim b() As Byte: b = s
Dim i As Long
For i = LBound(b) To UBound(b) Step 2
If isSurrogatePair(b, i) Then
i = i + 2
End If
xLen = xLen + 1
Next
End Function
Function xMid(ByVal s As String, ByVal st As Long, Optional ByVal ln As Long = 0) As String
If ln = 0 Then ln = Len(s)
Dim b() As Byte: b = s
Dim bOut() As Byte, iOut As Long
Dim i As Long, j As Long, cnt As Long
For i = LBound(b) To UBound(b) Step 2
cnt = cnt + 1
If cnt >= st Then
For j = i To i + IIf(isSurrogatePair(b, i), 3, 1)
ReDim Preserve bOut(iOut)
bOut(iOut) = b(j)
iOut = iOut + 1
Next
End If
If xLen(bOut) >= ln Then Exit For
If isSurrogatePair(b, i) Then i = i + 2
Next
xMid = bOut
End Function
Function xLeft(ByVal s As String, ByVal ln As Long) As String
xLeft = xMid(s, 1, ln)
End Function
Function xRight(ByVal s As String, ByVal ln As Long) As String
xRight = xMid(s, xLen(s) - ln + 1)
End Function
Function isSurrogatePair(ByRef b() As Byte, ByVal i As Long)
Dim h1 As Long, h2 As Long
isSurrogatePair = False
If i > UBound(b) - 3 Then Exit Function
h1 = b(i) + b(i + 1) * 256&
h2 = b(i + 2) + b(i + 3) * 256&
If h1 >= &HD800& And h1 <= &HDBFF& And _
h2 >= &HDC00& And h2 <= &HDFFF& Then
isSurrogatePair = True
End If
End Function
AscWのサロゲートペア対応版
シート関数のUNICODE関数もVBAのAscW関数もサロゲートペアに対応してません。
文字コードを調べる時に不便な時もあるので、ついでにAscWのサロゲートペア対応版も作成しておきました。
文字コードを調べる時に不便な時もあるので、ついでにAscWのサロゲートペア対応版も作成しておきました。
Function xAscW(ByVal s As String, Optional ByVal aPre As String = "0x", Optional ByVal aDelimit As String = " ") As String
Dim b() As Byte, i As Long, sRtn As String
b = s
For i = 0 To UBound(b) Step 2
sRtn = sRtn & aPre & Right("0000" & Hex(b(i + 1) * 256& + b(i)), 4) & aDelimit
Next
If Right(sRtn, 1) = aDelimit Then
sRtn = Left(sRtn, Len(sRtn) - 1)
End If
xAscW = sRtn
End Function
同じテーマ「ツイッター出題回答 」の記事
ツイッターで出されたVBAのお題（悪魔のCSV）をやってみた
ツイッターで出題されたVBAの問題をやってみました。ツイッターのエクセルおよびVBA関係の人達の間では、いろいろと面白く勉強になる問題を出し合うという事が行われています。フォローして参加してみると楽しいと思いますよ。
「VBAで導関数を求めよ」ツイッターのお題をやってみたツイッターで出題されたVBAの問題をやってみました。ツイッターのエクセルおよびVBA関係の人達の間で問題を出し合うという事が行われています。そんな中、現役高校生と思われる方からVBAの問題が出されました。
ツイッターのお題「君の名は？」ツイッターで出題されたVBAの問題をやってみました。ツイッターのエクセルおよびVBA関係の人達の間で問題を出し合うという事が行われています。今回のお題は以下になります。ツイートへのリンク お題：君の名は？ "-"ちゃんの名前がわかりません！教えてください。
ツイッターのお題「CSV編集」ツイッターに出されたお題をやってみるシリーズです。今回のお題は、CSV編集です。ツイートへのリンク https://twitter.com/i/status/1253307552802074625 VBSにしてみた VBAでも良いのですが、たまにはVBSも良いかと思い作ってみました。
アルファベットの26進（ツイッターお題）ツイッターで出されたお題をVBAで回答したものです。AAAの値をAAB,AAC...AAZまでインクリメントし、次のアルファベットを桁上げし、ABA,ABC?ZZZまで計算するコードを書きたい。お題のツイート https://twitter.com/KotorinChunChun/status/1262026213…
ナンバープレート数字遊び：ツイッターお題ツイッターで出されたお題をVBAで回答したものです。車のナンバープレートの4つの数字でやったりするお遊びです。ナンバーの4つの数字を四則演算で10にするというものです・【問題】 1-9までの数字が4つ与えられます それらを加減乗除を用いて10を作りたい その解答を全て列挙するプログラムを作成しなさい （解答なしの場…
サロゲートペアに対応した自作関数（Len,Left,Mid,Right）迷路にネコが挑戦したら、どうなるかな…
ツイッターで迷路を解くVBAが流行っていたので、それならと言う事で私も参加してみることに… 迷路の解き方は定番の方法がありますが、それらはツイッターの他の人に任せるとして、ちょっと独自の挑戦をしてみました。※これはジョークソフトです。続編もあります。
迷路ネコが影分身の術を体得したら…ツイッターで迷路を解くVBAが流行っていたので、ネコを迷路に挑戦させてみた… 迷路にネコが挑戦したら、どうなるかな… さすがに壁登りで迷路クリアは、、、ということで、ちゃんと迷路を攻略するようにネコを調教しました。ツイート 「壁登りは反則だろ」という厳しいご意見があったりなかったり… まうにゃんは厳しい躾けの末、
VBAで漢数字を算用数字に変換ツイッターで出題された問題に挑戦しました。漢数字を算用数字に変換するVBAを作成するお題です。出題ツイート 【お題】 VBAで漢数字を算用数字に変換してください。例:千八百万六千五百→18,006,500 カンマはあってもなくてもよいです。
新着記事NEW ・・・新着記事一覧を見る
ブール型（Boolean）のis変数・フラグについて｜VBA技術解説(2024-04-05)
テキストの内容によって図形を削除する｜VBA技術解説(2024-04-02)
ExcelマクロVBA入門目次｜エクセルの神髄(2024-03-20)
VBA10大躓きポイント（初心者が躓きやすいポイント）｜VBA技術解説(2024-03-05)
テンキーのスクリーンキーボード作成｜ユーザーフォーム入門(2024-02-26)
無効な前方参照か、コンパイルされていない種類への参照です。｜エクセル雑感(2024-02-17)
初級脱出10問パック｜VBA練習問題(2024-01-24)
累計を求める数式あれこれ｜エクセル関数応用(2024-01-22)
複数の文字列を検索して置換するSUBSTITUTE｜エクセル入門(2024-01-03)
いくつかの数式の計算中にリソース不足になりました。｜エクセル雑感(2023-12-28)
アクセスランキング ・・・ ランキング一覧を見る
1.最終行の取得（End,Rows.Count）｜VBA入門
2.セルのコピー&値の貼り付け（PasteSpecial）｜VBA入門
3.RangeとCellsの使い方｜VBA入門
4.ひらがな⇔カタカナの変換｜エクセル基本操作
5.繰り返し処理（For Next)｜VBA入門
6.変数宣言のDimとデータ型｜VBA入門
7.ブックを閉じる・保存（Close,Save,SaveAs）｜VBA入門
8.並べ替え（Sort）｜VBA入門
9.セルのクリア（Clear,ClearContents）｜VBA入門
10.Findメソッド（Find,FindNext,FindPrevious）｜VBA入門
このサイトがお役に立ちましたら「シェア」「Bookmark」をお願いいたします。
記述には細心の注意をしたつもりですが、
間違いやご指摘がありましたら、「お問い合わせ」からお知らせいただけると幸いです。
掲載のVBAコードは動作を保証するものではなく、あくまでVBA学習のサンプルとして掲載しています。
掲載のVBAコードは自己責任でご使用ください。万一データ破損等の損害が発生しても責任は負いません。